ANSYS 18.2 经典版APDL语言实例解析——第二弹,瞬态热分析。
发布网友
发布时间：1小时前
共1个回答
热心网友
时间：1小时前
本文将举例说明如何用ANSYS经典版实现简单的瞬态热分析。
瞬态热分析过程如下图所示：
在实际工作中，进行了20次循环计算，在下面的MACRO中简化了循环过程，只进行一次循环计算。
ALLSEL,ALL
！选择所有集合
/SOLU
！进入ANSYS的SOLUTION功能模块
LSCLEAR,ALL
！清除之前施加过的所有载荷。
NSPUL=5
NSDWEL=5
TIMEACT=0.001
！自定义以上3个变量，并赋值，后面会用到这些变量。TIMEACT表示当前时刻。NSPUL、NSDWEL表示载荷子步的步数。
ANTYPE,4
！定义分析类型的命令流，此处4 的意思是进行瞬态分析。
!***************************初始化计算开始***************************************
TIMINT,0
！暂时关掉瞬态分析的效果，对瞬态热分析模型进行温度场初始化求解。
KBC,0
！此命令流用于选择不同载荷步之间的载荷变化方式。0表示从上一个载荷步到下一个载荷步，载荷变化方式是线性插值方式，ANSYS help文档中称为ramped方式。1表示从上一个载荷步到下一个载荷步，载荷变化方式是跃变方式，ANSYS help文档中称为stepped方式。如下图(a)所示为stepped方式，载荷从载荷步1到载荷步2的第一个载荷子步变化时，没有过度阶段，直接跳到载荷步2对应的载荷值。如下图(b)所示为ramped方式，载荷从载荷步1到载荷步2变化时，载荷值呈一条直线逐渐变化至载荷步2对应的载荷值。
TIME,TIMEACT
！为载荷步设置时间步。从0时刻到0.001时刻为初始化计算载荷步。变量TIMEACT表示当前时刻，TIMEACT=0.001s。
/INPUT,VV_TEMP2,MAC
！/INPUT命令流用于读入提前编写好的文本文件。VV_TEMP2是提前写好的初始温度边界条件文件。此处要注意的是，要读入的文本文件和 .db模型文件不在同一根目录下时，需要在/INPUT命令流后面加上文本文件的存储地址。
NSUBST,1,1,1
！定义初始化计算的载荷步中的载荷子步。
OUTRES,ALL,NSOL
SOLVE
！求解，得到模型初始化温度分布。
!************************初始化计算结束******************************************
TIMEACT=TIMEACT+0.1
！变量TIMEACT表示当前时刻。TIMEACT=0.1001s。
TIMINT,1
！开启瞬态计算效果。
KBC,0
！采用ramped载荷变化方式。
TIME,TIMEACT
！定义载荷步的时间步：从0.001s时刻至0.1001s时刻，要将热载荷在0.1s内由零线性增加至所需的热载荷值。
/INPUT,CABLE_HEAT,MAC
/INPUT,CLAMP_HEAT,MAC
！读入热载荷文件，施加热载荷。
NSUBST,1,1,1
！定义载荷步的载荷子步。
OUTRES,ALL,NSOL
SOLVE
！求解。
TIMEACT=TIMEACT+450-0.1
！变量TIMEACT表示当前时刻。TIMEACT=450.001s。
TIMINT,1
！开启瞬态计算效果。
TIME,TIMEACT
！定义载荷步的时间步：从0.1001s时刻至450.001s时刻，模型热载荷保持不变，温度边界条件由初始温度线性增加至最大温度Tw。
KBC,0
！采用ramped载荷变化方式。
/INPUT,VV_TEMP,MAC
！读入温度边界条件文本文件，施加运行温度边界条件。
NSUBST,NSPUL,NSPUL,NSPUL
！定义载荷步的载荷子步。
OUTRES,ALL,NSOL
SOLVE
！求解。
TIMEACT=TIMEACT+0.1
！变量TIMEACT表示当前时刻。TIMEACT=450.1001s。
TIMINT,1
！开启瞬态计算效果。
TIME,TIMEACT
！定义载荷步的时间步：从450.001s时刻至450.1001s时刻，热载荷将线性变化减至零，运行温度边界条件保持不变。
KBC,0
！采用ramped载荷变化方式。
*DO,II,1,134,1
CMSEL,S,CM_%II%
ESLL,S
NSLE,S,1
BF,ALL,HGEN,0
*ENDDO
CMSEL,S,CLIP_CABLE_NODES
BF,ALL,HGEN,0
*DO,II,1011,1144,1
CMSEL,S,CLAMP_%II%
ESEL,R,TYPE,,1
NSLE,S,1
BF,ALL,HGEN,0
*ENDDO
！以上2个循环将模型的热载荷设为零。
ALLSEL,ALL
NSUBST,1,1,1
！定义载荷步的载荷子步。
OUTRES,ALL,NSOL
SOLVE
！求解。
TIMEACT=TIMEACT+1850-0.1
！变量TIMEACT表示当前时刻。TIMEACT=2300.001s。
TIMINT,1
！开启瞬态计算效果。
TIME,TIMEACT
！定义载荷步的时间步：从450.1001s时刻至2300.001s时刻，热载荷保持为零，运行温度边界条件线性减至初始温度边界条件。
KBC,0
！采用ramped载荷变化方式。
/INPUT,VV_TEMP2,MAC
！读入初始温度边界条件文件，施加初始温度边界条件。
NSUBST,NSDWEL,NSDWEL,NSDWEL
！定义载荷步的载荷子步。
OUTRES,ALL,NSOL
SOLVE
！求解。
至此，瞬态分析完成。
